FAQ (häufig gestellte Fragen)

letzte Änderung: 07.04.2004

Was mache ich, wenn etwas nicht funktioniert oder wenn die Ausgabe fehlerhaft ist?

Die erste Anlaufstelle für Fragen ist das Forum (Dialog). Bitte stelle mir keine Fragen zu den Anleitungen via E-Mail.

Bevor du aber im Forum eine Frage stellst, beachte bitte fogendes:

  • Wurde die Frage schon mal gestellt (evtl. mit Suchen prüfen)?
  • In einigen Fällen hilft dir auch dieses FAQ oder die rosa Links oberhalb des Forums weiter.
  • Schaue dir bei einer Fehlfunktion bitte erstmal das Log-File an (evtl. auch mit eingeschalteter Debug-Option) - wenn du nicht klarkommst, nimm den Log-File Checker zu Hilfe oder füge das Logfile über die Zwischenablage in deine Nachricht ein.
  • Ein Log-File mit eingeschalteter Debug-Option enthält auch immer das gesamte Dokument. Falls du es in deine Nachricht einfügen willst, drucke bitte nur ein sehr kleines Dokument.
  • Prüfe bitte auch vorab mit dem Log-File Checker , ob ein bekannter Fehler im Log-File aufgeführt wird.
  • Eine Angabe, wie "... druckt nicht" reicht nicht aus. Unter welchen Umständen passiert das: Aus welchem Programm; welche Rechnerumgebung (Netzwerk?) etc.
  • Bitte gebe immer an, unter welchem Betriebssystem es Probleme gibt, dafür gibt es extra ein Feld hinter dem Betreff.
  • Gebe an, wenn du etwas anders gemacht hast, als in meiner Anleitung beschrieben.
  • Wenn du meiner Anleitung nicht Schritt für Schritt gefolgt bist, hole dies nach, dort gibt es schon einige Hinweise.

nach oben


Was ist das Log-File und wo finde ich es?

Das Log-File ist die Protokolldatei von Redmon. In dieser Datei wird protokolliert, was bei der Ausführung von Redmon so alles geschieht. Funktioniert z.B. die Erstellung einer PDF-Datei nicht, sollte man mal einen Blick in das Log-File werfen, da dort alle Probleme aufgezeichnet werden. Gerade für Anfänger ist es aber sehr schwer die relevanten Informationen aus dem Log-File zu fischen und entsprechende Schlüsse zu ziehen. Aus diesem Grund habe ich den Log-File Checker geschrieben, welcher das Log-File auf Fehler untersucht. Für jeden bekannten Fehler gibt es die möglichen Ursachen und meistens auch einen Lösungsvorschlag aus. Der Log-File Checker ist die erste Adresse, wenn man bei Problemen nicht weiterkommt.

Es ist übrigens empfehlenswert, dem Log-File Checker ein Log-File zur Verarbeitung zu geben, bei welchem die Debug-Option aktiviert wurde.

Das Log-File findest du normalerweise bei C:\GS\pdf.log, je nachdem was du bei der Installation angegeben hast.

Falls du es nicht mehr genau weißt, musst du den Anschluss/Port (z.B. PDF1:) deines Druckertreibers (z.B. PDF-Datei) konfigurieren. Dort gelangst du dann in das Konfigurationsfenster von Redmon.

Wenn du hier auf Protokolldatei klickst, kommt der Dialog, wo du den Pfad deines Log-Files entnehmen kannst. Dort kannst du übrigens auch die Debug-Option aktivieren, was für die Fehleranalyse empfohlen wird.

nach oben

Wie kann ich mehrere einzelne PDF-Dateien in eine einzige PDF-Datei zusammenfügen (mergen)?

Um mehrere PDF-Dateien miteinander zu verbinden, kann man z.B. folgende Batchdatei (pdfmerge.bat) verwenden:

@echo off
SET GS=C:\GS\GS7.04
%GS%\bin\gswin32c.exe -dBATCH -dNOPAUSE -sDEVICE=pdfwrite -sOutputFile=C:\merged.pdf "%1" "%2" "%3" "%4" "%5" "%6" "%7" "%8" "%9"
echo.
echo fertig ... Datei liegt auf C:\ und heißt MERGED.PDF

Man kann nun per "Drag & Drop" mehrere (maximal 9) ausgewählte PDF-Dateien auf die Batchdatei ziehen, worauf die Datei Merged.pdf im Laufwerk C: erstellt wird. Evtl. muss die Batchdatei noch angepasst werden.

Da die Methode den Nachteil hat, dass die PDF-Datei neu interpretiert werden, findest du unter den Links kostenlose Tools, welche die Sache sauberer angehen und auch komfortabler sind. Empfehlenswert ist das kostenlose Tool GoBatchGS von Govert Knopper, welches die PDF-Dateien allerdings auch neu interpretiert. Es hat sich aber herausgestellt, dass es normalerweise kein Problem ist.

Wenn man noch die Originaldokumente besitzt oder ein Anwendungsprogramm an den vielen PDFs schuld ist, sollte man den hier beschriebenen Weg gehen, dabei werden auch keine PDF-Dateien neu interpretiert.

nach oben


Meine Anwendung erstellt für jede Seite eine eigene PDF-Datei, wie bekomme ich alle Seiten in eine PDF-Datei?

Die Sache ist etwas umständlich, aber es ist derzeit die einzige (mir bekannte) kostenlose Möglichkeit (Nur unter Win 2000/XP getestet). Excel-Anwender sollten übrigens erstmal diesen Forums-Beitrag lesen.

Man benötigt dazu erstmal einen neuen PDF-Drucker (z.B. PS-Sammler) bei welchem Redmon wie folgt konfiguriert ist:

Dann muss (ganz wichtig) entsprechend der Konfiguration das Unterverzeichnis makepdf im Verzeichnis C:\gs erstellt werden.

Nun fehlen noch zwei Dateien welche man am besten ebenfalls unter C:\gs ablegt.

alltopdf.bat

@echo off
set NAME=collected

set VERZEICHNIS=%USERPROFILE%\Desktop
set PSDIR=C:\gs\makepdf

C:\gs\gs7.05\bin\gswin32c -dNOSAFER @C:\gs\pdf.rsp -sOutputFile="%VERZEICHNIS%\%NAME%.pdf" -dBATCH -c save pop .setpdfwrite -f C:\gs\alltopdf.ps > "%VERZEICHNIS%\%NAME%.log"

findstr "Can't" "%VERZEICHNIS%\%NAME%.log"
if %ERRORLEVEL% == 1 goto Warning
findstr "Error" "%VERZEICHNIS%\%NAME%.log"
if %ERRORLEVEL% == 1 goto NOTOK

:OK
del "%VERZEICHNIS%\%NAME%.log"
del /q "%PSDIR%"
:Acrobat
start "" "%VERZEICHNIS%\%NAME%.pdf"
goto END
:Warning
start write "%VERZEICHNIS%\%NAME%.log"
goto Acrobat
:NOTOK
start write "%VERZEICHNIS%\%NAME%.log"
:END

alltopdf.ps

/PathName (C:\\gs\\makepdf\\*.ps) def

/RunDir {
{ /mysave save def
dup = flush
.runfile
clear cleardictstack
mysave restore
}
255 string
filenameforall
} def

PathName RunDir

Wenn man nun mit dem Drucker PS-Sammeln (Beispiel) ein mehrseitiges Dokument druckt, werden alle Postscript-Dateien in dem Ordner makepdf abgelegt.

Wenn das geschehen ist ruft man die Datei alltopdf.bat auf, welche dann eine PDF-Datei namens collected.pdf auf dem Desktop erzeugt und alle Dateien aus dem Ordner makepdf löscht.

Bei einem Verarbeitungsfehler wird übrigens automatisch das Log-File geöffnet.

nach oben


Wie kann ich Hyperlinks aus Word übernehmen?

Lösung mit GhostWord:

Im Grunde musst du dir nur GhostWord von Morten Juel installieren. Statt des Color LaserJet 4500 empfehle ich aber die Verwendung meiner PDF.PPD, welche du mittels winstger.exe von Adobe installiert hast. Dort musst du nur den Druckerport von PDF1: auf FILE: umstellen. Ansonsten geht der Rest eigentlich automatisch. Auch GhostWord nimmt Ghostscript zur Hilfe.

Alternative Lösung:

Diese Lösung war mir bis vor kurzem die einzige bekannte Möglichkeit die Hyperlinks aus Word in eine PDF-Datei zu übernehmen. Da ich beide Lösungen noch nicht verglichen habe, bleibt sie vorerst hier im FAQ stehen. Allerdings gehe ich davon aus, dass sie schlechter ist als die Lösung mit GhostWord.

Zuerst lädst du dir das Word-Macro PDFMaker 1.0 von Adobe runter und installierst es. Danach brauchst du noch die Datei FIX.REG welche du durch einen Doppelklick installieren kannst.

Nun brauchst du noch einen Postscript-Drucker der dem Namen "Distiller Assistant v3.0" trägt. Du kannst auch einen vorhandenen umbenennen. Wenn du nun Word startest, erscheint evtl. eine Fehlermeldung, dass PDFmaker.doc nicht gefunden werden kann. Dies kann man getrost ignorieren. Es sollte nun eine neue Symbolleiste mit dem Acrobat-Logo in Word zu sehen sein.

Klicke hier erstmal auf Prefs und deaktiviere folgende Optionen:

  • Report Errors
  • Delete .ps and .log files
  • View .pdf files
  • Send via email
  • prompt for filename

"Print via Distiller" muss auf jeden Fall aktiviert sein.

Zum Erstellen einer PDF mit Hyperlinks klickst du auf das Acrobat-Symbol. PDFMaker schreibt eine spezielle Postscriptdatei in das gleiche Verzeichnis wie das Dokument (oder Temp-Verzeichnis, falls Word-Dokument noch nicht gespeichert). Wenn Word fertig ist kannst du die PS-Datei mit GSView oder auch direkt mit ps2pdf (liegt unter C:\GS\gs7.04\lib\) in eine PDF-Datei mit Hyperlinks umwandeln.

Die Konfiguration ist etwas umständlich, da der PDFMaker eigentlich nur mit Adobe Acrobat funktioniert. Mittels der .reg-Datei und dem speziellen Druckernamen wird dem PDFMaker ein installierter Distiller vorgegaukelt (statt Distiller.exe einfach nur NUL: ). Dieser würde eigentlich nach dem schreiben der Postscript-Datei diese direkt in PDF wandeln. Ohne den Distiller bleibt aber noch die PS-Datei liegen, welche PDFmark-Anweisungen für die Hyperlinks enthält. Ich habe auch schon mal versucht die Sache automatisch an Ghostscript weiterleiten zu lassen, doch es hat bis jetzt nicht funktioniert, da der Dokumentname nicht bis nach Ghostscript ankommt. Ich habe die ganze Sache übrigens nur mit Windows 2000 und Word 2000 getestet.

Unter Windows 98 ist es unter umständen nötig in der FIX.REG (Rechte Maustaste/Bearbeiten) den : hinter "NUL" zu entfernen.

Im Forum gibt es auch einen entsprechenden Beitrag zum Thema.

nach oben

Wie kann ich einen PDF-Writer im Netzwerk freigeben?

Dazu muss man die Anschlusskonfiguration des PDF-Writer aufrufen und dort in Redmon die Parameter für gswin32c folgendermaßen anpassen:
@c:\gs\pdf.rsp -sOutputFile="c:\freigegebenes Verzeichnis\%u_%d.pdf" -c save pop .setpdfwrite -f -

Zudem muss man noch Ausgabe: auf Programm erledigt Ausgabe umstellen.

Natürlich muss der Drucker auch freigegeben werden und am besten gibt man ihm die Rechte "Jeder darf drucken".

Im Forum gibt es auch einen entsprechenden Beitrag zum Thema, der sich auch mit größeren Netzen befasst.

nach oben

Wie kann ich eine PDF-Datei direkt erstellen, ohne dass immer nach dem Dateinamen gefragt wird?

Lösung 1:

In der Anschlusskonfiguration des PDF-Writer muss man in Redmon die Argumente für gswin32c folgendermaßen anpassen:

@c:\gs\pdf.rsp -sOutputFile="c:\%d.pdf" -c save pop .setpdfwrite -f -

Zudem muss man noch Ausgabe: auf Programm erledigt Ausgabe umstellen.

Lösung 2:

Die zweite Lösung ist etwas aufwändiger, doch dafür erhält die PDF-Datei unter einigen Betriebssystemen den korrekten Dateinamen und die LOG-Datei wird bei einem Fehler automatisch angezeigt.

Derzeit scheint das allerdings nur unter Windows XP vernünftig zu funktionieren, selbst der Verwendung der aktuellen XP-Treiber unter Windows 2000 bringen keinen Erfolg. Wie es bei anderen Betriebssystemen aussieht, kann ich nicht sagen. Wer Erfahrungen damit gesammelt hat, kann diese ja mal im Forum mitteilen.

Und so geht man vor: Man verändert in der Anschlusskonfiguration des PDF-Writer die Redmon-Einstellung wie im Screenshot zu sehen:

Nun muss man noch die Datei PDF.BAT in einem Texteditor (z.B. NOTEPAD.EXE) mit folgendem Inhalt erstellen:

Windows 9x (pdf-win95.bat):
@echo off
set VERZEICHNIS=C:\Windows\Desktop

C:\gs\gs7.04\bin\gswin32c @C:\gs\pdf.rsp -sOutputFile="%VERZEICHNIS%\%REDMON_DOCNAME%.pdf" -dBATCH -c save pop .setpdfwrite -f %1 > "%VERZEICHNIS%\%REDMON_DOCNAME%.log"

if %ERRORLEVEL% == 255 goto OK
write "%VERZEICHNIS%\%REDMON_DOCNAME%.log"
start "Acrobat" "%VERZEICHNIS%\%REDMON_DOCNAME%.pdf"
goto END
:OK
del "%VERZEICHNIS%\%REDMON_DOCNAME%.log"
:END
Windows NT/2000/XP (pdf-winnt.bat):

@echo off
for %%I IN ("%REDMON_DOCNAME%") DO @set NAME=%%~nI

set VERZEICHNIS=C:\Dokumente und Einstellungen\%REDMON_USER%\Desktop

  rem WINDOWS NT >>> set VERZEICHNIS=C:\winnt\profiles\%REDMON_USER%\Desktop

C:\gs\gs7.04\bin\gswin32c @C:\gs\pdf.rsp -sOutputFile="%VERZEICHNIS%\%NAME%.pdf" -dBATCH -c save pop .setpdfwrite -f %1 > "%VERZEICHNIS%\%NAME%.log"

findstr "Can't" "%VERZEICHNIS%\%NAME%.log"
if %ERRORLEVEL% == 0 goto Warning
findstr "Error" "%VERZEICHNIS%\%NAME%.log"
if %ERRORLEVEL% == 0 goto NOTOK

:OK
del "%VERZEICHNIS%\%NAME%.log"
:Acrobat
start "Acrobat" "%VERZEICHNIS%\%NAME%.pdf"
goto END
:Warning
start write "%VERZEICHNIS%\%NAME%.log"
goto Acrobat
:NOTOK
start write "%VERZEICHNIS%\%NAME%.log"
:END

Die NT/2000/XP-Lösung hat noch den Vorteil, dass z.B. bei einem Excel-Dokument die PDF-Datei nicht "Dokument.XLS.PDF" heißt, sondern "Dokument.PDF". Zudem wird bei einem Verarbeitungsfehler automatisch das Log-File geöffnet.

Die PDF-Datei wird bei meinem Vorschlag auf dem Desktop erstellt, falls nicht oder falls es Probleme gibt, muss man hinter set VERZEICHNIS= einen anderen Pfad angeben.

Zusätzlich wird noch eine LOG-Datei erstellt, welche bei erfolgreicher PDF-Erstellung automatisch gelöscht wird (Befehl del). Bei einem Fehler bleibt die LOG-Datei auf dem Desktop und wird automatisch angezeigt.

nach oben

Wie kann ich einen Ordner überwachen, so dass neue Postscript-Dateien automatisch in PDFs umgewandelt werden? (wie beim Acrobat Distiller)

Unter Windows 2000/XP (NT müsste auch gehen) geht das mit einer Batch-Datei (gswatch.bat), wie weiter unten aufgeführt. Sobald man die Batch-Datei startet, läuft sie in einer Endlosschleife ab und wandelt umgehend eintreffende Dateien um. Falls die Datei schon verarbeitet wird, obwohl sie noch nicht komplett in dem überwachten Ordner liegt (Zugriff gesperrt), gibt's zwar eine unschöne Fehlermeldung, aber man kann sie ignorieren. Falls jemand die Batch-Datei noch perfektioniert, soll er diese doch bitte im Forum posten.

Als Alternative zur Batch-Datei empfiehlt sich das kostenlose Tool GoBatchGS von Govert Knopper. Die Batch-Datei hat nämlich den Nachteil, dass die Prozessorbelastung recht hoch ist.

Unter Windows 95/98/Me ist so eine Batchdatei ohne Zusatzprogramme nicht möglich, es gibt aber eine Shareware von M. Tesch (PDF.exe) , die das erledigt.

@echo off
cls
set GS=C:\gs\gs7.05
set IN_FOLDER=C:\gs\in
set OUT_FOLDER=C:\gs\out
set DEL_OR_MOVE=move
set WATCH_TEMP=C:\temp\gswatch.tmp

echo Rumborak Verzeichnisüberwachung (gsWatch 0.1)
echo =========================================================================
echo Das Verzeichnis %IN_FOLDER% wird ständig auf neue Dateien überwacht.
echo Sobald eine neue Datei gefunden wird, wird automatisch eine PDF-Datei
echo im %OUT_FOLDER% erzeugt.
if %DEL_OR_MOVE%==move echo Die Ursprungsdaten werden darauf von %IN_FOLDER% && echo nach %OUT_FOLDER% verschoben.
if %DEL_OR_MOVE%==del echo Die Ursprungsdaten werden danach gelöscht.
echo =========================================================================
echo.
echo *** Verzeichnisüberwachung aktiv ...

:LOOP
if NOT exist "%IN_FOLDER%\*.*p*" goto LOOP

echo.
echo *** neue Dateien werden verarbeitet ...
dir /b C:\gs\in\*.* > %WATCH_TEMP%
for /F %%I IN (%WATCH_TEMP%) DO echo %DATE%, %TIME% - %%I && %GS%\bin\gswin32c.exe @C:\gs\pdf.rsp -sOutputFile="%OUT_FOLDER%\%%~nI.pdf" -dBATCH -c save pop .setpdfwrite -f "%IN_FOLDER%\%%I" > "%IN_FOLDER%\%%~nI.log"
echo.
echo *** Fehlerprotokolle:
for %%I IN ("%IN_FOLDER%\*.log") DO findstr "Error" "%%I" > NUL && IF %ERRORLEVEL%==1 move "%%I" "%OUT_FOLDER%\" && echo %%I
for %%I IN ("%IN_FOLDER%\*.log") DO findstr "can't" "%%I" > NUL && IF %ERRORLEVEL%==1 move "%%I" "%OUT_FOLDER%\" && echo %%I
IF EXIST "%IN_FOLDER%\*.log" del /Q "%IN_FOLDER%\*.log"
if %DEL_OR_MOVE%==move for /F %%I IN (%WATCH_TEMP%) DO move "%IN_FOLDER%\%%I" "%OUT_FOLDER%\"
if %DEL_OR_MOVE%==del for /F %%I IN (%WATCH_TEMP%) DO del "%IN_FOLDER%\%%I"
echo.
echo *** Durchlauf beendet
echo -------------------------------------------------------------------------
goto LOOP

nach oben


Wie kann ich eine Postscript-Datei erzeugen, ohne dass sie in eine PDF-Datei umgewandelt wird?

Der einfachste Weg wäre, wenn man den Anschluss des PDF-Writers von PDF1: auf FILE: umstellt.

Unter Umständen ist es aber praktischer, wenn man nicht nach dem Dateinamen gefragt wird, sondern die Datei z.B. direkt auf dem Desktop abgelegt wird. Dazu erstellt man am besten einen neuen "umgeleiteten" Anschluss und stellt ihn wie folgt ein:

Je nach Betriebssystem müssen folgende Argumente angegeben werden:

Windows 9x
"C:\Windows\Desktop\%d.ps"
Windows NT
"C:\winnt\profiles\%u\Desktop\%d.ps"
Windows 2000/XP
"C:\Dokumente und Einstellungen\%u\Desktop\%d.ps"

Falls auf ein Laufwerk im Netz geschrieben werden soll, muss man noch Ausführung als Benutzer ankreuzen.

%u bedeutet, dass dort der Benutzername eingesetzt wird und für %d wird der Dokument- bzw. Job-Name eingesetzt, je nach Betriebssystem.

nach oben

Wie bekomme ich vor dem Drucken eine Seitenvorschau?

Das geht recht einfach mit Redrun (gehört zu Redmon) und GSView, hier die Einstellung in Redmon:

Du kannst dann ganz normal mit GSView das Dokument ausdrucken bzw. daraus eine PDF erzeugen.

nach oben


Welche Variabeln gibt es in Redmon?

Folgende Variablen gibt es in Redmon:

Name Verwendungszweck Bemerkung
%1 Gibt den Dateinamen aus, welcher bei "Prompt for Filename" im Dateidialog eingegeben wurde.  
%u Gibt den aktuellen Benutzernamen von Windows aus.  
%d Gibt den aktuellen Job- oder Dokumentnamen aus. Derzeit bekommt man damit nur unter Windows XP den echten Dokumentnamen ausgegeben, alle anderen Betriebssysteme geben einen Jobnamen mit Jobnummer aus.
%h Gibt die für den Druckjob gültige Handlenummer aus. Nur sinnvoll bei Verwendung von "Kopiere Befehlskette auf den Drucker" als Ausgabeparameter.
%%0?d Dient zur Erzeugung von durchnummerierten Dateien. Das Fragezeichen muss durch eine Zahl ersetzt werden, welche die Anzahl der Stellen angibt. Also %%03d bedeutet 001 und %%05d bedeutet 00001 usw.. Funktioniert nur, wenn von Redmon an Redfile.exe umgeleitet wird. Das doppelte %-Zeichen ist wichtig.
%REDMON_USER% siehe %u Lässt sich bei Windows NT/2000/XP nicht direkt in Redmon ansprechen, sondern nur in einer Batchdatei, welche durch Redrun.exe (statt gswin32c.exe) aufgerufen wird.
%REDMON_DOCNAME% siehe %d Lässt sich bei Windows NT/2000/XP nicht direkt in Redmon ansprechen, sondern nur in einer Batchdatei, welche durch Redrun.exe (statt gswin32c.exe) aufgerufen wird.
%REDMON_MACHINE% Gibt den Rechnernamen als UNC-Pfad aus. (z.B. "\\Rechner" Lässt sich bei Windows NT/2000/XP nicht direkt in Redmon ansprechen, sondern nur in einer Batchdatei, welche durch Redrun.exe (statt gswin32c.exe) aufgerufen wird.
%REDMON_PRINTER& Gibt den Namen des Druckers aus. (z.B. "PDF-Datei") Lässt sich bei Windows NT/2000/XP nicht direkt in Redmon ansprechen, sondern nur in einer Batchdatei, welche durch Redrun.exe (statt gswin32c.exe) aufgerufen wird.
%REDMON_JOB% Gibt die Jobnummer als ganze Zahl aus. Lässt sich bei Windows NT/2000/XP nicht direkt in Redmon ansprechen, sondern nur in einer Batchdatei, welche durch Redrun.exe (statt gswin32c.exe) aufgerufen wird.
%REDMON_PORT% Gibt den Anschlussnamen aus. (z.B. "PDF1:" Lässt sich bei Windows NT/2000/XP nicht direkt in Redmon ansprechen, sondern nur in einer Batchdatei, welche durch Redrun.exe (statt gswin32c.exe) aufgerufen wird.
%REDMON_SESSIONID% Enthält die ID der aktuellen Client-Sitzung im Windows-Terminal-Server-Umfeld. Der Wert ist null, wenn keine Terminal-Dienste aktiv sind.

Lässt sich bei Windows NT/2000/XP nicht direkt in Redmon ansprechen, sondern nur in einer Batchdatei, welche durch Redrun.exe (statt gswin32c.exe) aufgerufen wird.
nach oben